Готика ½ Spell_Logic - увеличения урона заклинаний

[MW 7]

хотелось бы отразить возможность увеличения урона от заклинаний непосредственно в Spell_Logic.

возьмём в качестве примера Spell_Firebolt. у подобных заклинаний используется один уровень заклинания, но совершенного ничего не мешает увеличить кол-во уровней, уменьшив при этом урон за уровень.

const int SPL_Cost_Firebolt        = 5;
const int SPL_Damage_Firebolt     = 5; // MDK 25

instance Spell_Firebolt (C_Spell_Proto)
{
    time_per_mana            = 0;
    damage_per_level        = SPL_Damage_Firebolt;
    damageType                = DAM_MAGIC;
};

переходим непосредственно к Spell_Logic

func int Spell_Logic_Firebolt (var int manaInvested)
{
    var C_Item  itm; // для будущих проверок
    var C_NPC   her;     her = Hlp_GetNpc(PC_Hero); // ссылка на инстанцию героя

1. сделаем проверку на то есть ли мана на каст. если маны не хватает, то выходим. в моём примере проверка делается один раз при (manaInvested == 0)

    var int SPL_Cost_mana; 
    if (manaInvested == 0)
    {
        SPL_Cost_mana = SPL_Cost_Firebolt;  // необходимо маны для руны
        if (Npc_GetActiveSpellIsScroll(self))   { SPL_Cost_mana = SPL_Cost_Scroll; };  // необходимо маны для свитка
 
        if (self.attribute[ATR_MANA] < SPL_Cost_mana)   { return SPL_SENDSTOP; };
    };

2. в данном примере что бы заклинание наносило 25 ущерба надо использовать 5ый уровень заклинания. Этот уровень я задаю как "базовый", а далее начинаю начислять "бонусные" уровни. "Уровни" я записываю в аивер НПС. Подсчёт "уровней" я делаю на "старте" в Spell_Logic пока (manaInvested == 0).

        if (manaInvested == 0)
        {
            self.aivar[AIV_SpellLevel] = 5;
            //
            //  Бонусы
            //
            var C_NPC her;     her = Hlp_GetNpc(PC_Hero);

            if (self.guild == GIL_KDF)
            {
                self.aivar[AIV_SpellLevel] += 1;
 
                if (Hlp_GetInstanceID(self)==Hlp_GetInstanceID(her))
                && (heroGIL_KDF2 == TRUE)
                {
                    self.aivar[AIV_SpellLevel] += 1;
                };
            };
 
            var C_Item itm; itm = Npc_GetEquippedMeleeWeapon(self);
            if (Hlp_IsItem(itm, ITMW_ADDON_STAB01) == TRUE)
            {
                self.aivar[AIV_SpellLevel] += 1;
            }
            else if (Hlp_IsItem(itm, ITMW_ADDON_STAB04) == TRUE)
            {
                self.aivar[AIV_SpellLevel] += 2;
            };

               if (Npc_HasEquippedArmor(self) == TRUE)
            {
                itm = Npc_GetEquippedArmor(self);
                if (Hlp_IsItem(itm, ITAR_KDF_L) == TRUE)
                {
                    self.aivar[AIV_SpellLevel] += 1;
                }
                else if  (Hlp_IsItem(itm, ITAR_KDF_H) == TRUE)
                {
                    self.aivar[AIV_SpellLevel] += 2;
                };
 
                if (KDF01_Equipped == TRUE)
                && (KDFArmor_Equipped == TRUE)
                {
                    self.aivar[AIV_SpellLevel] += 1;
                };
            };
 
            if (Hlp_GetInstanceID(self)==Hlp_GetInstanceID(her))
            {
                if (PLAYER_TALENT_RUNES [SPL_Firebolt] == true)         { self.aivar[AIV_SpellLevel] += 1; };
                if (PLAYER_TALENT_RUNES [SPL_InstantFireball] == true)  { self.aivar[AIV_SpellLevel] += 1; };
                if (PLAYER_TALENT_RUNES [SPL_Firestorm] == true)        { self.aivar[AIV_SpellLevel] += 1; };
                if (PLAYER_TALENT_RUNES [SPL_ChargeFireball] == true)   { self.aivar[AIV_SpellLevel] += 1; };
                if (PLAYER_TALENT_RUNES [SPL_Pyrokinesis] == true)      { self.aivar[AIV_SpellLevel] += 1; };
                if (PLAYER_TALENT_RUNES [SPL_Firerain] == true)         { self.aivar[AIV_SpellLevel] += 1; };
            };
        };

код выше можно вынести в отдельную функцию что бы использовать в разных спелл_логик. в приведённом выше примере есть различные проверки по всему что пришло в голову. после каждой положительной проверки уровень заклинания "поднимался" всё выше и выше, то есть получался "бонус". а там где есть бонусы там могут быть и штрафы ;-) а значит эти условия можно сделать более проработанными и начислять как бонусы так и штрафы. При этом всё таки кол-во уровней должно быть осмысленное и не уходить в бесконечность. Например если "базовый" уровень 5, то максимально возможный лучшей сделать 10. Если уровней будет много(например 100), то каст заклинание может занять значительное время.
upd доп информация по проверкам в посте #2 Готика ½ - Spell_Logic - увеличения урона заклинаний

3. Переходим к непосредственному повышению уровня: определяем текущий уровень заклинания и если он ниже необходимого, то повышаем уровень.

    var int    SpellLevel; SpellLevel = Npc_GetActiveSpellLevel(self);
    //Hlp_PrintConsole(Str_Format("Spell_Logic_Firebolt[%s %i] // manainvested =%i, Spell Lvl = %i", self.name, self.id,manaInvested, SpellLevel));

    if (SpellLevel < self.aivar[AIV_SpellLevel])
    {
        return SPL_NEXTLEVEL;
    };

4. обнуляем аивер и отнимает ману движком.

    if (self.aivar[AIV_SpellLevel] != 0)
    {
        self.aivar[AIV_SpellLevel] = 0;
        return SPL_FORCEINVEST + Spl_Cost_Mana; // отнимает ману. устанавливаем новое значение manainvested.
    };

5. сам каст

    return SPL_SENDCAST;
};

в функции каста делается запись в аивер НПС AIV_SelectSpell. В оригинальных скриптах это делается для врагов, что бы они при необходимости могли поменять заклинание. Огненную стрелу использует только герой. тем не менее я на всякий случай оставляю данный счётчик. Ввиду того что ману я отнимаю движком, скриптовое отнимание маны убрано из Spell_Cast_***. Подробнее про то как и зачем отнимать ману движком я написал в посте #5 Готика ½ - Spell_Logic - увеличения урона заклинаний

func void Spell_Cast_Firebolt()
{
    self.aivar[AIV_SelectSpell] += 1;     // счётчик для НПС (не герой)
};

 

[MW 7]

Я могу такую же картинку сделать:

не сможешь. у меня цвета были;-)

Зачем ты сравниваешь базовый и максимальный уровни заклинаний, если подобная ситуация исключается?

это у тебя в голове она исключается. а в игре вполне себе может быть;-)

Ты предлагаешь соблюдать строгое равенство минимального и максимального уровней заклинаний разных кругов?

я ничего "не предлагаю", в моей системе координат это какая то дичь из каких то других игр.

таблицу свою я привёл в качестве примера показав в ней логические связи, которые можно отразить в какой то общей функции, что бы использоваться её для всех "огненных" заклинаний.

Я остановился на таком варианте, только зарядов хочется сделать не 4, а 3:

да ты не стесняй себя. меняй каждый месяц ;-)

Поджигание​

поджигание это прекрасно. триггер на горение уже написал? ;-d или оно само по себе будет как то поджигаться?

Т.е. прописать наращивание уровней для каждой ступени? Тогда сделать меньше уровней, прописав для каждого заряда разный урон за 1 SplLvl?

смотри сообщение от ElderGamer которое ты лайкнул.

АОЕ

АОЕ это доп эффект? а какой основной эффект тогда?

Что это значит?

это значит что ты будешь делать "водные" заклинания. потом "неожиданно" поймёшь что надо сбалансировать после них огненные и так далее.

 

[KirTheSeeker]

это у тебя в голове она исключается. а в игре вполне себе может быть;-)

Приведи конкретный пример?

 

[MW 7]

> Зачем ты сравниваешь базовый и максимальный уровни заклинаний, если подобная ситуация исключается?

> Приведи конкретный пример?

Герой с бонусами. Шаман орков без бонусов.

 

[KirTheSeeker]

> Зачем ты сравниваешь базовый и максимальный уровни заклинаний, если подобная ситуация исключается?

> Приведи конкретный пример?

Герой с бонусами. Шаман орков без бонусов.

Это справедливо, если шаман применяет тот же огненный шар. Но даже в этом случае должен действовать бонус от маны.

 

[SQ_RT]

Решил потестить файл в шапке темы, но почему-то на базе неоф. обновления вылетает при запуске следующая ошибка:

Если строку с HEROGIL_KDF2 закомментить, ошибка вылетает все равно, но уже с отсылаясь к строке с if (KDF01_Equipped == TRUE)
Если комментить и эту строку, то:

В чем может быть проблема?

 

[MW 7]

Здравствуйте! Подскажите пожалуйста: хочу разобраться в руне "Кулак Ветра", да и в целом во всех рунах с "зарядкой". Где вообще прописывается вот эта способность заряжать тот же кулак, чтобы получить больше урона и откинуть, там же отдельная анимация даже есть на это?

1. в Spell_Logic_WindFist заклинания надо использовать return SPL_NEXTLEVEL. чем выше уровень заклинания тем больший урон он будет наносить.
2. в инстанции спела указывается тип урона. у кулака ветра это damageType = DAM_FLY;