C_Item // прототипы

[MW 7]

Ковырялся в старых проектах. повыкладываю функции "прототипы" для инстанций Item

 

[MW 7]

резерв

 

[MW 7]

Оружие

func void B_ItMw_TEXTCOUNT()
{
    item.description    =   item.name;
    item.TEXT[2]        =   NAME_Damage;        item.COUNT[2]    = item.damageTotal;
    item.TEXT[3]         =   NAME_Str_needed;    item.COUNT[3]    = item.cond_value[2];
    
    if      (item.flags & ITEM_AXE)          { item.TEXT[4] = NAME_OneHanded; }
    else if (item.flags & ITEM_SWD)          { item.TEXT[4] = NAME_OneHanded; }
    else if (item.flags & ITEM_2HD_SWD)      { item.TEXT[4] = NAME_TwoHanded; }
    else if (item.flags & ITEM_2HD_AXE)      { item.TEXT[4] = NAME_TwoHanded; };
    
    if item.value > 0                   { item.TEXT[5] = NAME_Value;        item.COUNT[5] = item.value; };
};

 

[MW 7]

Доспехи

func void B_Prt_ItAr(var string name,
                        var int EDGE,
                        var int BLUNT,
                        var int POINT,
                        var int FIRE,
                        var int MAGIC)
{
    item.mainflag       =    ITEM_KAT_ARMOR;
    item.flags          =    0;
   
    item.visual = ConcatStrings("ItAr_", name);
    item.visual = ConcatStrings(item.visual, ".3ds");
   
    item.visual_change = ConcatStrings("Armor_", name);
    item.visual_change = ConcatStrings(item.visual_change, ".asc");
   
     item.wear           =    WEAR_TORSO;
    item.material       =    MAT_LEATHER; 
   
    item.protection[PROT_EDGE]  = EDGE;
    item.protection[PROT_BLUNT] = BLUNT;
    item.protection[PROT_POINT] = POINT;
    item.protection[PROT_FIRE]  = FIRE;
    item.protection[PROT_MAGIC] = MAGIC;

    // текстовое поле
    item.description    = item.name;
    if item.protection[PROT_EDGE]  > 0  { item.TEXT[1] = NAME_Prot_Edge;    item.COUNT[1] = item.protection[PROT_EDGE]; };
    if item.protection[PROT_POINT] > 0  { item.TEXT[2] = NAME_Prot_Point;   item.COUNT[2] = item.protection[PROT_POINT];};
    if item.protection[PROT_FIRE]  > 0  { item.TEXT[3] = NAME_Prot_Fire;    item.COUNT[3] = item.protection[PROT_FIRE]; };
    if item.protection[PROT_MAGIC] > 0  { item.TEXT[4] = NAME_Prot_Magic;   item.COUNT[4] = item.protection[PROT_MAGIC];};
    if item.value > 0                   { item.TEXT[5] = NAME_Value;        item.COUNT[5] = item.value;                 }; 
};

инстанции из Аддона

// ******************************************************
INSTANCE ITAR_PIR_L_Addon (C_Item)
{
    name                     =    "Piratenkleidung";
    value                     =    VALUE_ITAR_PIR_L_Addon;
    B_Prt_ItAr("Pir_L_Addon",40,40,40,0,0);
};

// ******************************************************
instance ITAR_PIR_M_Addon (C_Item)
{
    name                     =    "Piratenrьstung";
    value                     =    VALUE_ITAR_PIR_M_Addon;
    B_Prt_ItAr("PIR_M_ADDON",55,55,55,0,0);
};

// ******************************************************
instance ITAR_PIR_H_Addon (C_Item)
{
    name                     =    "Kapitдns Kleidung";
    value                     =    VALUE_ITAR_PIR_H_Addon;
    B_Prt_ItAr("PIR_H_ADDON",60,60,60,0,0);
};

// ******************************************************
instance ITAR_Bloodwyn_Addon (C_Item)
{
    name                     =    "Bloodwyn Rьstung";
    value                     =    VALUE_ITAR_Bloodwyn_Addon;
    B_Prt_ItAr("Bloodwyn_ADDON",70,70,70,0,0);

};
// ******************************************************
INSTANCE ITAR_Thorus_Addon (C_Item)
{
    name                     =    "Schwere Gardistenrьstung";
    value                     =    VALUE_ITAR_Thorus_Addon;
    B_Prt_ItAr("Thorus_ADDON",70,70,70,0,0);
};

// ******************************************************
instance ITAR_Raven_Addon (C_Item)
{
    name                     =    "Ravens Rьstung";
    value                     =    VALUE_ITAR_Raven_Addon;
    B_Prt_ItAr("Raven_ADDON",100,100,100,100,100);
};



// ******************************************************
instance ITAR_RANGER_Addon (C_Item)
{
    name                     =    "Rьstung des 'Rings des Wassers'";
    value                     =    VALUE_ITAR_Ranger_Addon;
    B_Prt_ItAr("Ranger_ADDON",50,50,50,0,10);

};

// ******************************************************
INSTANCE ITAR_Fake_RANGER (C_Item)
{
    name                     =    "zerissene Rьstung";
    value                     =    VALUE_ITAR_Ranger_Addon;
    B_Prt_ItAr("Ranger_ADDON",0,0,0,0,0);
};

// ******************************************************
INSTANCE ITAR_KDW_L_Addon (C_Item)
{
    name                     =    "Leichte KDW";
    value                     =    VALUE_ITAR_KDW_L_Addon;
    B_Prt_ItAr("KDW_L_ADDON",50,50,50,25,25);
};



// ******************************************************
INSTANCE ITAR_MayaZombie_Addon (C_Item)
{
    name                     =    "alte Rьstung";
    value                     =    0;
    B_Prt_ItAr("Raven_ADDON",50,50,50,50,50);
    //visual                     =    "ItAr_Raven_ADDON.3ds";
    visual_change             =    "Armor_MayaZombie_Addon.asc";
};


////////////////////////////////////////////////////////////////////////////////
//
//    Magische Rьstungen
//
instance ItAr_FireArmor_Addon (C_Item)
{
    name                     =    "Magische Rьstung";
    value                     =    VALUE_ITAR_XARDAS;
    B_Prt_ItAr("Xardas",100,100,100,50,50);
    wear                     =    WEAR_TORSO | WEAR_EFFECT;
    effect                    =    "SPELLFX_FIREARMOR";
};