Вопросы по скриптингу

MaGoth · 28 Сен 2007

Прежде чем задавать вопросы, ознакомьтесь с документацией..
1) Читать онлайн
2) Архив с офлайн-версией(chm) во вложении

MW 7 · 23 Апр 2023

MW 7 · 23 Апр 2023

KirTheSeeker написал(а):
возможно ли "родными скриптами игры"

Да. Только лучше заранее продумать место откуда она будет вызываться. что бы не вызывать её по сто раз из разных мест. я бы вызывал её из кровати.

Daedalus:

func void B_Hero_SetModelFatness(var C_Npc slf)
{
    if (Npc_IsPlayer(slf) == true)
    {
        var int STR_SetModelFatness;
        var float fatness;
        
        STR_SetModelFatness = ATR_Training[ATR_STRENGTH] + ATR_PermBonus[ATR_STRENGTH];

        if      (STR_SetModelFatness >= 150)    { fatness = 2;      }
        else if (STR_SetModelFatness >= 135)    { fatness = 1.6 ;   }
        else if (STR_SetModelFatness >= 120)    { fatness = 1.2 ;   }
        else if (STR_SetModelFatness >= 105)    { fatness = 0.8 ;   }
        else if (STR_SetModelFatness >= 90)     { fatness = 0.4 ;   }
        else if (STR_SetModelFatness >= 75)     { fatness = 0   ;   }
        else if (STR_SetModelFatness >= 60)     { fatness = -0.4;   }
        else if (STR_SetModelFatness >= 45)     { fatness = -0.8;   }
        else if (STR_SetModelFatness >= 30)     { fatness = -1.2;   }
        else if (STR_SetModelFatness >= 15)     { fatness = -1.6;   }
        else                                    { fatness = -2  ;   };

        Mdl_SetModelFatness(slf,fatness);       
    };
};

p.s.
по моему в G1 MDK была привязка Mdl_SetModelFatness к силе НПС.

KirTheSeeker · 23 Апр 2023

MW 7 написал(а):
Только лучше заранее продумать место откуда она будет вызываться. что бы не вызывать её по сто раз из разных мест. я бы вызывал её из кровати.

Т.е. когда ГГ взаимодействует с кроватью и спит? Пожалуй, мне нравится.

MW 7 · 23 Апр 2023

KirTheSeeker написал(а):
Т.е. когда ГГ взаимодействует с кроватью и спит?

это же твой мод. вот тебе и решать где вызывать эту функцию ;-)

Пост автоматически объединён: 23 Апр 2023

KirTheSeeker написал(а):
Пожалуй, мне нравится.

Daedalus:

func void PC_Sleep(var int t)
{
    ...
    B_Hero_SetModelFatness(self);
    ...
};

Пост автоматически объединён: 23 Апр 2023

if (STR_SetModelFatness >= 150) { fatness = 2; }
else if (STR_SetModelFatness >= 135) { fatness = 1.6 ; }
else if (STR_SetModelFatness >= 120) { fatness = 1.2 ; }
else if (STR_SetModelFatness >= 105) { fatness = 0.8 ; }
else if (STR_SetModelFatness >= 90) { fatness = 0.4 ; }
else if (STR_SetModelFatness >= 75) { fatness = 0 ; }
else if (STR_SetModelFatness >= 60) { fatness = -0.4; }
else if (STR_SetModelFatness >= 45) { fatness = -0.8; }
else if (STR_SetModelFatness >= 30) { fatness = -1.2; }
else if (STR_SetModelFatness >= 15) { fatness = -1.6; }
else { fatness = -2 ; };

а можно и наверное и так

Код:

fatness = (STR_SetModelFatness - 100) * 2 / 100 ;
if (fatness > 2) { fatness = 2;      } 
else if (fatness < -2) { fatness =  -2;      } ;

KirTheSeeker · 24 Апр 2023

KirTheSeeker написал(а):
Подскажите, пожалуйста, возможно ли "родными скриптами игры" сделать функцию или т.п. позволяющую внедрить динамичное изменение только для ГГ Mdl_SetModelFatness (толщина персонажа), в зависимости от "родного" показателя силы (sPerm_STR_KTS = ATR_Training[ATR_STRENGTH] + ATR_PermBonus[ATR_STRENGTH])?

Мда, "похудение" до Mdl_SetModelFatness(self,-2) для ГГ противопоказано:

Есть идеи, как эту прорезь на поясе можно поправить?
Полагаю, можно попробовать скорректировать это через Mdl_SetModelScale, выставив например Mdl_SetModelScale(slf,1,1,0.98); , пока ГГ не достигнет Mdl_SetModelFatness = 0 (на данном значении прорези уже не видно). Подскажите, пожалуйста, как это правильно дописать в B_Hero_SetModelFatness ?

ElderGamer · 24 Апр 2023

KirTheSeeker написал(а):
Mdl_SetModelScale(slf,1,1,0.98);

Требует тестирования. В мод-фиксе увеличил одному неписю рост таким вот образом, так он начал подпрыгивать при появлении в кадре.

KirTheSeeker написал(а):
Есть идеи, как эту прорезь на поясе можно поправить?

Можно править модели всех доспехов-тел, доступных ГГ, в которых наблюдается такой вот разрыв. В мод-фиксе правились модели доспехов послушников Братства, у которых подобное наблюдается при нулевой толстости. Но этот путь, надо полагать, "не для всех".

KirTheSeeker · 24 Апр 2023

ElderGamer написал(а):
Можно править модели всех доспехов-тел, доступных ГГ, в которых наблюдается такой вот разрыв.

При надетых доспехах (какие успел проверить) прорезь не наблюдается, кстати.

MW 7 · 24 Апр 2023

KirTheSeeker написал(а):
Есть идеи, как эту прорезь на поясе можно поправить?

D36 правила модельки доспехов. Используй её архив с моделями.

KirTheSeeker · 24 Апр 2023

MW 7 написал(а):
D36 правила модельки доспехов. Используй её архив с моделями.

Подскажи, пожалуйста, где его можно найти? В мастерской Steam я подобного файла не нахожу, как и соответствующей темы на форуме.
Или речь об этом?

MW 7 · 24 Апр 2023

KirTheSeeker написал(а):
Подскажи, пожалуйста, где его можно найти?

Споси у Доси в её топике Готика 2: НВ - Неофициальное обновление для Г2 НВ

KirTheSeeker · 29 Апр 2023

Приветствую всех вновь.

MW 7 написал(а):
это же твой мод. вот тебе и решать где вызывать эту функцию ;-)

Пост автоматически объединён: 23 Апр 2023

Daedalus:

func void PC_Sleep(var int t) { ... B_Hero_SetModelFatness(self); ... };

Пост автоматически объединён: 23 Апр 2023

а можно и наверное и так

Код:

fatness = (STR_SetModelFatness - 100) * 2 / 100 ; if (fatness > 2) { fatness = 2; } else if (fatness < -2) { fatness = -2; } ;

Благодарю, такой варианта работает.
Но при таком коде почему-то дублируются варианты диалога в кровати (т.е. по два варианта - "до утра", "до утра", "до полудня", "до полудня" и т.д.)

Код:

...

func void PC_Sleep(var int t)
{
    AI_StopProcessInfos(self);
    PLAYER_MOBSI_PRODUCTION = MOBSI_NONE;
    self.aivar[AIV_INVINCIBLE] = FALSE;
    B_Hero_SetModelFatness(self);
    if(Wld_IsTime(0,0,t,0))
    {
        Wld_SetTime(t,0);
    }
    else
    {
        t += 24;
        Wld_SetTime(t,0);
    };
    Wld_StopEffect("DEMENTOR_FX");
    if(SC_IsObsessed == TRUE)
    {
        PrintScreen(PRINT_SleepOverObsessed,-1,-1,FONT_Screen,2);
    }
    else
    {
//        B_Say_Overlay(hero,hero,"$AWAKE");
        PrintScreen(PRINT_SleepOver,-1,-1,FONT_Screen,2);
        BeerDay = 0;
        hero.attribute[ATR_HITPOINTS] = hero.attribute[ATR_HITPOINTS_MAX];
        hero.attribute[ATR_MANA] = hero.attribute[ATR_MANA_MAX];
    };
    if(Parlan_DontTalkToNovice == LOG_FAILED)
    {
        Parlan_DontTalkToNovice = LOG_Running;
    };
    B_CheckLog();
    B_CoolHotDraw(hero);
    B_ClearFakeItems(hero);
//    PrintGlobals(PD_ITEM_MOBSI);
    Npc_SendPassivePerc(hero,PERC_ASSESSENTERROOM,NULL,hero);
};
...

Подскажите, пожалуйста, в чём может быть проблема?

MW 7 · 29 Апр 2023

KirTheSeeker написал(а):
Подскажите, пожалуйста, в чём может быть проблема?

файл целиком скинь

KirTheSeeker · 29 Апр 2023

MW 7 написал(а):
файл целиком скинь

Daedalus:

func void sleepabit_s1()
{
    if(C_NpcIsHero(self) || C_NpcIsRockefeller(self))
    {
        self.aivar[AIV_INVINCIBLE] = TRUE;
        PLAYER_MOBSI_PRODUCTION = MOBSI_SleepAbit;
        AI_ProcessInfos(self);
        if(SC_IsObsessed == TRUE)
        {
            Wld_PlayEffect("DEMENTOR_FX",hero,hero,0,0,0,FALSE);
        };
    };
};

func void PC_Sleep(var int t)
{
    AI_StopProcessInfos(self);
    PLAYER_MOBSI_PRODUCTION = MOBSI_NONE;
    self.aivar[AIV_INVINCIBLE] = FALSE;
    B_Hero_SetModelFatness(self);
    if(Wld_IsTime(0,0,t,0))
    {
        Wld_SetTime(t,0);
    }
    else
    {
        t += 24;
        Wld_SetTime(t,0);
    };
    Wld_StopEffect("DEMENTOR_FX");
    if(SC_IsObsessed == TRUE)
    {
        PrintScreen(PRINT_SleepOverObsessed,-1,-1,FONT_Screen,2);
    }
    else
    {
//        B_Say_Overlay(hero,hero,"$AWAKE");
        PrintScreen(PRINT_SleepOver,-1,-1,FONT_Screen,2);
        BeerDay = 0;
        hero.attribute[ATR_HITPOINTS] = hero.attribute[ATR_HITPOINTS_MAX];
        hero.attribute[ATR_MANA] = hero.attribute[ATR_MANA_MAX];
    };
    if(Parlan_DontTalkToNovice == LOG_FAILED)
    {
        Parlan_DontTalkToNovice = LOG_Running;
    };
    B_CheckLog();
    B_CoolHotDraw(hero);
    B_ClearFakeItems(hero);
//    PrintGlobals(PD_ITEM_MOBSI);
    Npc_SendPassivePerc(hero,PERC_ASSESSENTERROOM,NULL,hero);
};

instance PC_NoSleep(C_Info)
{
    npc = PC_Hero;
    nr = 999;
    condition = PC_NoSleep_Condition;
    information = PC_NoSleep_Info;
    important = FALSE;
    permanent = TRUE;
    description = Dialog_Ende;
};


func int PC_NoSleep_Condition()
{
    if(PLAYER_MOBSI_PRODUCTION == MOBSI_SleepAbit)
    {
        return TRUE;
    };
};

func void PC_NoSleep_Info()
{
    AI_StopProcessInfos(self);
    Wld_StopEffect("DEMENTOR_FX");
    self.aivar[AIV_INVINCIBLE] = FALSE;
    PLAYER_MOBSI_PRODUCTION = MOBSI_NONE;
};


instance PC_SleepTime_Morning(C_Info)
{
    npc = PC_Hero;
    nr = 1;
    condition = PC_SleepTime_Morning_Condition;
    information = PC_SleepTime_Morning_Info;
    important = FALSE;
    permanent = TRUE;
    description = "—пать до утра";
};


func int PC_SleepTime_Morning_Condition()
{
    if(PLAYER_MOBSI_PRODUCTION == MOBSI_SleepAbit)
    {
        return TRUE;
    };
};

func void PC_SleepTime_Morning_Info()
{
    PC_Sleep(8);
};


instance PC_SleepTime_Noon(C_Info)
{
    npc = PC_Hero;
    nr = 2;
    condition = PC_SleepTime_Noon_Condition;
    information = PC_SleepTime_Noon_Info;
    important = FALSE;
    permanent = TRUE;
    description = "—пать до полудн¤";
};


func int PC_SleepTime_Noon_Condition()
{
    if(PLAYER_MOBSI_PRODUCTION == MOBSI_SleepAbit)
    {
        return TRUE;
    };
};

func void PC_SleepTime_Noon_Info()
{
    PC_Sleep(12);
};


instance PC_SleepTime_Evening(C_Info)
{
    npc = PC_Hero;
    nr = 3;
    condition = PC_SleepTime_Evening_Condition;
    information = PC_SleepTime_Evening_Info;
    important = FALSE;
    permanent = TRUE;
    description = "—пать до вечера";
};


func int PC_SleepTime_Evening_Condition()
{
    if(PLAYER_MOBSI_PRODUCTION == MOBSI_SleepAbit)
    {
        return TRUE;
    };
};

func void PC_SleepTime_Evening_Info()
{
    PC_Sleep(20);
};


instance PC_SleepTime_Midnight(C_Info)
{
    npc = PC_Hero;
    nr = 4;
    condition = PC_SleepTime_Midnight_Condition;
    information = PC_SleepTime_Midnight_Info;
    important = FALSE;
    permanent = TRUE;
    description = "—пать до полуночи";
};


func int PC_SleepTime_Midnight_Condition()
{
    if(PLAYER_MOBSI_PRODUCTION == MOBSI_SleepAbit)
    {
        return TRUE;
    };
};

func void PC_SleepTime_Midnight_Info()
{
    PC_Sleep(0);
};


instance PC_SleepTime_Dawn(C_Info)
{
    npc = PC_Hero;
    nr = 5;
    condition = PC_SleepTime_Dawn_Condition;
    information = PC_SleepTime_Dawn_Info;
    important = FALSE;
    permanent = TRUE;
    description = "—пать до рассвета";
};


func int PC_SleepTime_Dawn_Condition()
{
    if(PLAYER_MOBSI_PRODUCTION == MOBSI_SleepAbit)
    {
        return TRUE;
    };
};

func void PC_SleepTime_Dawn_Info()
{
    PC_Sleep(5);
};

MW 7 · 29 Апр 2023

KirTheSeeker написал(а):
Но при таком коде почему-то дублируются варианты диалога в кровати (т.е. по два варианта - "до утра", "до утра", "до полудня", "до полудня" и т.д.)

если ты ложишь файл в папку авторан то у тебя в файле должна быть только та функция в которые ты вносишь изменения, то есть функция PC_Sleep

]

Daedalus:

func void PC_Sleep(var int t)
{
    AI_StopProcessInfos(self);
    PLAYER_MOBSI_PRODUCTION = MOBSI_NONE;
    self.aivar[AIV_INVINCIBLE] = FALSE;
    B_Hero_SetModelFatness(self);
    if(Wld_IsTime(0,0,t,0))
    {
        Wld_SetTime(t,0);
    }
    else
    {
        t += 24;
        Wld_SetTime(t,0);
    };
    Wld_StopEffect("DEMENTOR_FX");
    if(SC_IsObsessed == TRUE)
    {
        PrintScreen(PRINT_SleepOverObsessed,-1,-1,FONT_Screen,2);
    }
    else
    {
//        B_Say_Overlay(hero,hero,"$AWAKE");
        PrintScreen(PRINT_SleepOver,-1,-1,FONT_Screen,2);
        BeerDay = 0;
        hero.attribute[ATR_HITPOINTS] = hero.attribute[ATR_HITPOINTS_MAX];
        hero.attribute[ATR_MANA] = hero.attribute[ATR_MANA_MAX];
    };
    if(Parlan_DontTalkToNovice == LOG_FAILED)
    {
        Parlan_DontTalkToNovice = LOG_Running;
    };
    B_CheckLog();
    B_CoolHotDraw(hero);
    B_ClearFakeItems(hero);
//    PrintGlobals(PD_ITEM_MOBSI);
    Npc_SendPassivePerc(hero,PERC_ASSESSENTERROOM,NULL,hero);
};

KirTheSeeker · 29 Апр 2023

MW 7 написал(а):
если ты ложишь файл в папку авторан то у тебя в файле должна быть только та функция в которые ты вносишь изменения, то есть функция PC_Sleep

Не знал, благодарю.

KirTheSeeker · 30 Апр 2023

Приветствую всех вновь. Не получается найти в скриптах неоф. обновления скрижаль одноручки III (ItWr_OneHStonePlate3), но насколько помню она находится в сундуке перед Вороном.
Возможно ли через скрипты редактировать содержание сундуков в игре? Или это можно увидеть и поменять только через Spacer?

MW 7 · 30 Апр 2023

KirTheSeeker написал(а):
Возможно ли через скрипты редактировать содержание сундуков в игре? Или это можно увидеть и поменять только через Spacer?

1. увидеть можно в файле мира открыв его в программе(Spacer, Spacer.NET, блокнот и т.д.)
2. поменять можно отредактировав файл мира в программе(Spacer, Spacer.NET, блокнот и т.д.)
3. добавить / удалить можно через скрипты, если:
* сундук имеет уникальное имя если
* есть понимание как его "определить" через скрипты
* если использовать zParserExtender

KirTheSeeker · 8 Май 2023

Приветствую всех.
Подскажите, пожалуйста, есть ли в скриптах переменная, которая отслеживает количество приготовленных игроком зелий?

D36 · 8 Май 2023

KirTheSeeker написал(а):
Приветствую всех.
Подскажите, пожалуйста, есть ли в скриптах переменная, которая отслеживает количество приготовленных игроком зелий?

TotalPotionsBrewed в 29 версии неофициального обновления. Если у тебя такой переменной нет, то добавь счетчик TotalPotionsBrewed += 1 в B_BrewPotion.

KirTheSeeker · 11 Май 2023

Приветствую всех. Вопрос по скриптам неоф. обновления Г2НВ:
- Подскажите, пожалуйста, где прописываются требования для изучения зелий? Я имею в виду, например, чтобы соблюдалась последовательность появления диалогов при обучении "эссенция - экстракт - эликсир".
- Для корректного добавления дополнительных требований править нужно B_GetLearnCostTalent.d или B_TeachPlayerTalentAlchemy.d ?

Daedalus:

func int B_GetLearnCostTalent(var C_Npc oth,var int talent,var int skill)
{
    
    if(talent == NPC_TALENT_ALCHEMY)
    {
        if(skill == POTION_Health_01)
        {
            if(ClassicAlchemy == FALSE)
            {
                kosten = 1;
            }
            else
            {
                kosten = 2;
            };
        }
        else if(skill == POTION_Health_02)
        {
            kosten = 4;
        }
        else if(skill == POTION_Health_03)
        {
            kosten = 6;
        }
        else if(skill == POTION_Health_04)
        {
            kosten = 8;
        }
        else if(skill == POTION_Mana_01)
        {
            if(ClassicAlchemy == FALSE)
            {
                kosten = 1;
            }
            else
            {
                kosten = 2;
            };
        }
        else if(skill == POTION_Mana_02)
        {
            kosten = 4;
        }
        else if(skill == POTION_Mana_03)
        {
            kosten = 6;
        }
        else if(skill == POTION_Mana_04)
        {
            kosten = 8;
        }
        else if(skill == POTION_Speed)
        {
            kosten = 4;
        }
        else if(skill == POTION_Perm_STR)
        {
            if(ClassicAlchemy == FALSE)
            {
                kosten = 20;
            }
            else
            {
                kosten = 8;
            };
        }
        else if(skill == POTION_Perm_DEX)
        {
            if(ClassicAlchemy == FALSE)
            {
                kosten = 20;
            }
            else
            {
                kosten = 10;
            };
        }
        else if(skill == POTION_Perm_Mana)
        {
            kosten = 8;
        }
        else if(skill == POTION_Perm_Health)
        {
            kosten = 8;
        }
        else if(skill == POTION_MegaDrink)
        {
            kosten = 5;
        };
    };

    return kosten;
};

Daedalus:

func int B_TeachPlayerTalentAlchemy(var C_Npc slf,var C_Npc oth,var int potion)
{
    var int kosten;
    kosten = B_GetLearnCostTalent(oth,NPC_TALENT_ALCHEMY,potion);
    if(oth.lp < kosten)
    {
        PrintScreen(PRINT_NotEnoughLP,-1,-1,FONT_ScreenSmall,2);
        B_Say(slf,oth,"$NOLEARNNOPOINTS");
        return FALSE;
    };
    oth.lp -= kosten;
    if(Npc_GetTalentSkill(oth,NPC_TALENT_ALCHEMY) == 0)
    {
        Npc_SetTalentSkill(oth,NPC_TALENT_ALCHEMY,1);
        Log_CreateTopic(TOPIC_TalentAlchemy,LOG_NOTE);
        Log_AddEntry(TOPIC_TalentAlchemy,"Чтобы сварить зелье, мне нужна пустая мензурка и необходимые для этого зелья ингредиенты. Из этих ингредиентов я могу приготовить зелье на алхимическом столе.");
    };
    if(potion == POTION_Health_01)
    {
        PLAYER_TALENT_ALCHEMY[POTION_Health_01] = TRUE;
        B_LogEntry(TOPIC_TalentAlchemy,"Ингредиенты для 'ЛЕЧЕБНОЙ ЭССЕНЦИИ': 2 лечебные травы и 1 луговой горец.");
    }
    else if(potion == POTION_Health_02)
    {
        PLAYER_TALENT_ALCHEMY[POTION_Health_02] = TRUE;
        B_LogEntry(TOPIC_TalentAlchemy,"Ингредиенты для 'ЛЕЧЕБНОГО ЭКСТРАКТА': 2 лечебных растения и 1 луговой горец.");
    }
    else if(potion == POTION_Health_03)
    {
        PLAYER_TALENT_ALCHEMY[POTION_Health_03] = TRUE;
        B_LogEntry(TOPIC_TalentAlchemy,"Ингредиенты для 'ЛЕЧЕБНОГО ЭЛИКСИРА': 2 лечебных корня и 1 луговой горец.");
    }
    else if(potion == POTION_Mana_01)
    {
        PLAYER_TALENT_ALCHEMY[POTION_Mana_01] = TRUE;
        B_LogEntry(TOPIC_TalentAlchemy,"Ингредиенты для 'ЭССЕНЦИИ МАНЫ': 2 огненных крапивы и 1 луговой горец.");
    }
    else if(potion == POTION_Mana_02)
    {
        PLAYER_TALENT_ALCHEMY[POTION_Mana_02] = TRUE;
        B_LogEntry(TOPIC_TalentAlchemy,"Ингредиенты для 'ЭКСТРАКТА МАНЫ': 2 огненных травы и 1 луговой горец.");
    }
    else if(potion == POTION_Mana_03)
    {
        PLAYER_TALENT_ALCHEMY[POTION_Mana_03] = TRUE;
        B_LogEntry(TOPIC_TalentAlchemy,"Ингредиенты для 'ЭЛИКСИРА МАНЫ': 2 огненных корня и 1 луговой горец");
    }
    else if(potion == POTION_Speed)
    {
        PLAYER_TALENT_ALCHEMY[POTION_Speed] = TRUE;
        B_LogEntry(TOPIC_TalentAlchemy,"Ингредиенты для 'ЗЕЛЬЯ УСКОРЕНИЯ': 1 снеппер-трава и 1 луговой горец");
    }
    else if(potion == POTION_Perm_STR)
    {
        PLAYER_TALENT_ALCHEMY[POTION_Perm_STR] = TRUE;
        B_LogEntry(TOPIC_TalentAlchemy,"Ингредиенты для 'ЭЛИКСИРА СИЛЫ': 1 драконий корень и 1 царский щавель.");
    }
    else if(potion == POTION_Perm_DEX)
    {
        PLAYER_TALENT_ALCHEMY[POTION_Perm_DEX] = TRUE;
        B_LogEntry(TOPIC_TalentAlchemy,"Ингредиенты для 'ЭЛИКСИРА ЛОВКОСТИ': 1 гоблинская ягода и 1 царский щавель.");
    }
    else if(potion == POTION_Perm_Mana)
    {
        PLAYER_TALENT_ALCHEMY[POTION_Perm_Mana] = TRUE;
        B_LogEntry(TOPIC_TalentAlchemy,"Ингредиенты для 'ЭЛИКСИРА ДУХА': 1 огненный корень и 1 царский щавель.");
    }
    else if(potion == POTION_Perm_Health)
    {
        PLAYER_TALENT_ALCHEMY[POTION_Perm_Health] = TRUE;
        B_LogEntry(TOPIC_TalentAlchemy,"Ингредиенты для 'ЭЛИКСИРА ЖИЗНИ': 1 лечебный корень и 1 царский щавель.");
    };
    if((Opened_LousHammer == TRUE) && (Knows_LousHammer == FALSE))
    {
        B_LogEntry(TOPIC_TalentAlchemy,"Ингредиенты для 'МОЛОТА ЛУ': 1 вода, 2 репы, 1 болотная трава, 1 зуб болотной акулы и 1 ром.");
        Knows_LousHammer = TRUE;
    };
    if((Opened_Schlafhammer == TRUE) && (Knows_Schlafhammer == FALSE))
    {
        B_LogEntry(TOPIC_TalentAlchemy,"Ингредиенты для двойного 'МОЛОТА ЛУ': 1 'Молот Лу' и 1 ром.");
        Knows_Schlafhammer = TRUE;
    };
    if((Opened_SchnellerHering == TRUE) && (Knows_SchnellerHering == FALSE))
    {
        B_LogEntry(TOPIC_TalentAlchemy,"Ингредиенты для 'БЫСТРОЙ СЕЛЕДКИ': 1 вода, 1 ром, 1 рыба и 1 снеппер-трава.");
        Knows_SchnellerHering = TRUE;
    };
    if((Opened_MushroomMana == TRUE) && (Knows_MushroomMana == FALSE))
    {
        B_LogEntry(TOPIC_TalentAlchemy,"Ингредиенты для 'ГРИБНОГО ЭКСТРАКТА': 50 черных грибов и 1 луговая ягода.");
        Knows_MushroomMana = TRUE;
    };
    if((Opened_AppleSTR == TRUE) && (Knows_AppleSTR == FALSE))
    {
        B_LogEntry(TOPIC_TalentAlchemy,"Ингредиенты для 'ЯБЛОЧНОГО ЭКСТРАКТА': 25 яблок и 1 лесная ягода.");
        Knows_AppleSTR = TRUE;
    };
    if((Opened_MegaDrink == TRUE) && (PLAYER_TALENT_ALCHEMY[POTION_MegaDrink] == FALSE))
    {
        B_LogEntry(TOPIC_TalentAlchemy,"Ингредиенты для 'ЭМБАРЛА ФИРГАСТО': 10 драконьих яиц, 1 черная жемчужина и 1 сера.");
        PLAYER_TALENT_ALCHEMY[POTION_MegaDrink] = TRUE;
    };
    PrintScreen(PRINT_LearnAlchemy,-1,-1,FONT_Screen,2);
    return TRUE;
};

Вопросы по скриптингу

★★★★★★★★★★★Администратор

Вложения

Модостроитель

Модостроитель

Участник форума

Модостроитель

Участник форума

Модостроитель

Участник форума

Модостроитель

Участник форума

Модостроитель

Участник форума

Модостроитель

Участник форума

Вложения

Модостроитель

Участник форума

Участник форума

Модостроитель

Участник форума

Модостроитель

Участник форума

★★★★★★★★★★★
Администратор