Не стесняюсь спросить....

[Oxbow]

Не так. AR_ - это причина атаки. Attack Reason
Это влияет на окончание боя и память о нём.
None - просто подраться.
GuardStopsIntruder - причиной является попытка пройти охрану. И охранники убьют , если победит. Но точно запомнят.

А есть где-то список этих AR? Например, если я хочу, чтобы дрались насмерть.

 

[MEG@VOLT]

А есть где-то список этих AR? Например, если я хочу, чтобы дрались насмерть.

АР_КИЛЛ

https://worldofplayers.ru/threads/37749/

// ------ Причина нападения ------------

 

[ElderGamer]

вот это должно сработать (код ниже 01)?

Не совсем. Тут следует учесть особенность работы движка при обработке инстанций диалогов. Если просто прописать вызов функции старта атаки для третьего непися в инстанции диалога, то непись будет переведён в состояние атаки сразу же после старта диалога. ГГ будет болтать о чём-то с одним неписем, а другой непись в это время вытащит саблю, может быть, что-то грозное пробурчит и будет терпеливо ждать, пока диалог закончится. Согласись, выглядит хреново.

Начинать атаку после завершения диалога может только собеседник ГГ. Также он может по завершению диалога быть принудительно переведён в иное состояние, и этим следует воспользоваться для реализации описанных тобой ситуаций. Требуется написать особое ZS-состояние для непися собеседника ГГ. ZS-состояние обычно состоит из трёх функций (стартовая, циклическая, завершающая). Но в данном случае, думаю, будет достаточно только стартовой функции. Во всяком случае, в Г1 движок такое проглатывает. Что нужно сделать. По пунктам. В инстанции диалога прописать не старт атаки, а перевод собеседника ГГ в особое состояние. Функцию использовать ту же, что для старта атаки в функции B_Attack - AI_StartState, если не напутал с названием. Написать функцию состояния типа void c названием, начинающимся с "ZS_". Например, func void ZS_Npc1Start Attack(). В этой функции прописать старт атаки для нужных неписей с указанием целей и причин атаки.

 

[MW 7]

Не совсем. Тут следует учесть особенность работы движка при обработке инстанций диалогов.

вариант из MDK от пираний

func void DIA_Rumbold_HALLO_ENDAttack ()
{
    AI_StopProcessInfos (self);
    B_Attack (self, other, AR_KILL, 1);

    if (Hlp_IsValidNpc (Rick))
    && (!C_NpcIsDown (Rick))
    {
        B_Attack (Rick, other, AR_KILL, 1);
    };
};

MDK пираньи	улучшенная с использованием AI_StartState по схеме ElderGamer
func void DIA_Rumbold_HALLO_Attack () { AI_Output (other, self, "DIA_Rumbold_HALLO_Attack_15_00"); //Ich bin euer schlimmster Albtraum. AI_Output (self, other, "DIA_Rumbold_HALLO_Attack_10_01"); //Du bist ein toter Mann! Info_ClearChoices (DIA_Rumbold_HALLO); Info_AddChoice (DIA_Rumbold_HALLO, DIALOG_ENDE, DIA_Rumbold_HALLO_ENDAttack ); };	func void DIA_Rumbold_HALLO_Attack () { AI_Output (other, self, "DIA_Rumbold_HALLO_Attack_15_00"); //Ich bin euer schlimmster Albtraum. AI_Output (self, other, "DIA_Rumbold_HALLO_Attack_10_01"); //Du bist ein toter Mann! Info_ClearChoices (DIA_Rumbold_HALLO); AI_StartState (self, DIA_Rumbold_HALLO_ENDAttack ,1,""); };

 

[Beowulf]

Scarecrow, посмотрел твои файлы - да, музыка проигрывается единожды. зацикливание через скрипты и спейсер не помогли. После посмотрел это урок - скорее всего при создании сегмента упущен этот момент:

Спойлер

В левой части окна по правой кнопке мыши вызовите свойства вашего сегмента - Properties. Здесь можно изменить его длину - Length, в закладке Loop установите галочку Infinite, т.е. зациклить произведение в бесконечный цикл.

 

[Oxbow]

Подскажите как работает рутина TA_Repair_Hut
Не могу в Спейсере найти мобов с Repair в названии.

 

[D36]

Не могу в Спейсере найти мобов с Repair в названии.

REPAIR_PLANK

Учти, что эти объекты невидимы (showVisual:FALSE) и выделить их можно только из списка объектов:

 

[MW 7]

Подскажите как работает рутина TA_Repair_Hut

нпс "ремонтирует". бывает что не ремонтирует

FUNC int ZS_Repair_Hut_Loop ()
{
    // ------ Hдmmern ------
    if (!C_BodyStateContains(self, BS_MOBINTERACT_INTERRUPT))
    && (Wld_IsMobAvailable(self,"REPAIR"))
    {
        AI_UseMob (self, "REPAIR", 1);
    };
    
    // ------ Random-Ani beim Hдmmern ------
    if (Npc_GetStateTime(self) > 5)
    && (C_BodyStateContains(self, BS_MOBINTERACT_INTERRUPT))
    {
        var int zufall; zufall = Hlp_Random(100); 
    
           if (zufall < 50)
        {
            AI_PlayAniBS (self, "T_REPAIR_RANDOM_1", BS_MOBINTERACT_INTERRUPT);
        };
        
        Npc_SetStateTime (self, 0);
    };
    
    return LOOP_CONTINUE;
};

 

[Oxbow]

Подскажите, есть в игре проверка на избиение?
Я знаю, что есть проверка на убийство/смерть Npc_IsDead(Vino). Ну, а если я хочу, добавить задание избить НПС, но не убивать, как это можно сделать?

 

[D36]

Подскажите, есть в игре проверка на избиение?
Я знаю, что есть проверка на убийство/смерть Npc_IsDead(Vino). Ну, а если я хочу, добавить задание избить НПС, но не убивать, как это можно сделать?

if(!Npc_IsDead(Vino))
{
    if(Vino.aivar[AIV_DefeatedByPlayer] == TRUE)
    {
        //Вино жив и избит игроком
    };
};

 

[MW 7]

добавлю пять копеек: констант две и они в какой то степени друг друга дублирует, с той лишь разницей что AIV_VictoryXPGiven так же учитывает избиение НПС напарником ГГ, а AIV_DefeatedByPlayer только героем.

AIV_VictoryXPGiven

    // ------ XP ------
    if ( Npc_IsPlayer(other) || (other.aivar[AIV_PARTYMEMBER]==TRUE) )
    && (self.aivar[AIV_VictoryXPGiven] == FALSE)
    {
        B_GivePlayerXP (self.level * XP_PER_VICTORY);
        
        self.aivar[AIV_VictoryXPGiven] = TRUE;
    };

AIV_DefeatedByPlayer

    if (self.guild < GIL_SEPERATOR_HUM)
    && (Npc_IsPlayer(other))                                
    {
        self.aivar[AIV_DefeatedByPlayer] = TRUE; //wird nur hier gesetzt, nie verдndert!
        self.aivar[AIV_LastFightAgainstPlayer] = FIGHT_LOST;
        
        if (self.aivar[AIV_LastPlayerAR] == AR_NONE)
        && (self.aivar[AIV_DuelLost] == FALSE) //also nur EINMAL
        && (self.guild == GIL_SLD)
        {
            Sld_Duelle_gewonnen = Sld_Duelle_gewonnen + 1;
            self.aivar[AIV_DuelLost] = TRUE;
        };
    
        if (self.aivar[AIV_ArenaFight] == AF_RUNNING)
        {
            self.aivar[AIV_ArenaFight] = AF_AFTER;
        };
    };

 

[Beowulf]

Подскажите, есть в игре проверка на избиение?
Я знаю, что есть проверка на убийство/смерть Npc_IsDead(Vino). Ну, а если я хочу, добавить задание избить НПС, но не убивать, как это можно сделать?

Дополню камрадов: не всякого нпс можно просто избить. Сразу к праотцам уходят следующие категории нпс-людей (достаточно одного из условий)
1) В скриптах нпс есть такая строка

aivar[AIV_DropDeadAndKill] = TRUE;

2) Нпс принадлежит к гильдии "Бандит"
3) Нпс принадлежит к гильдии "Ищущий"

 

[Oxbow]

Подскажите где можно отредактировать изначальное наполнение инвентаря ГГ.
И можно как-то отредактировать в Сорсере состав катсцен, а то в сборке которую я компилирую на основе декомпилированных скриптов нет первой катсцены (ту, где Ксардас призывает Братка).

 

[ElderGamer]

Подскажите где можно отредактировать изначальное наполнение инвентаря ГГ.

В инстанции непися ему в инвентарь обычно кладут всё, что нужно. Для торговцев существует иное решение, по понятным причинам.

можно как-то отредактировать в Сорсере состав катсцен

Поиск по проекту. Функция PlayVideo. Если я правильно понял вопрос.

 

[Oxbow]

Поиск по проекту. Функция PlayVideo. Если я правильно понял вопрос.

func void B_Extro_Avi()
{
    if((Npc_IsDead(PC_Thief_DI) == FALSE) && (Npc_IsDead(PC_Fighter_DI) == FALSE))
    {
        DiegAndGornAreOnboard = TRUE;
    };
    PlayVideo("Extro_Xardas.BIK");
    PlayVideo("Credits_Extro.BIK");
    PlayVideo("Credits2.BIK");
    if(DiegAndGornAreOnboard == TRUE)
    {
        PlayVideo("Extro_AllesWirdGut.BIK");
    };
    ExitSession();
};

Вроде эта так катсцена самая первая? Где лежат эти файлы?

В инстанции непися ему в инвентарь обычно кладут всё, что нужно. Для торговцев существует иное решение, по понятным причинам.

Я имею ввиду, где можно отредактировать тему с тем, что в начале игры у ГГ все виды лута (оружие, доспехи) и 10000 золота, Как это убрать или наоборот добавить новые свои доспехи?

 

[MW 7]

Вроде эта так катсцена самая первая?

это финальное видео.

 

[Oxbow]

это финальное видео.

Нашел правильное, оно было в Startup и почему-то закомменчено.

Пост автоматически объединён: 20 Ноя 2022

Подскажите как работает функция Npc_GetNearestWP и почему нельзя сделать вот так:

func int dia_Peter_Meet_condition()
{
    if((PeterGoMeet == TRUE) && (Npc_GetNearestWP (Peter) == "NW_CITY_HABOUR_11"))
    {
        return TRUE;
    };
};

 

[D36]

почему нельзя сделать вот так:

Результатом выполнения функции Npc_GetNearestWP(npc) является строка с названием точки, ближайшей к npc. Для сравнения строк string следует использовать только функцию Hlp_StrCmp(text1,text2):

func int dia_Peter_Meet_condition()
{
    if((PeterGoMeet == TRUE) && Hlp_StrCmp(Npc_GetNearestWP(Peter),"NW_CITY_HABOUR_11"))
    {
        return TRUE;
    };
};

Оператор == используется только для сравнения целых чисел int.

 

[Сахар]

Каким скриптом редактируется в Г2 количество полученного опыта за NPC людей, если строка "level" в их инстанциях отсутствует?

 

[LikerGothic]

Сахар, level есть всегда, оно наследуется из прототипа либо установлено в 0, либо в скриптах далее идет проверка если 0, то подменяется значение в функции получения опыта за драку/убийство, т.е в zs_dead или zs_unconscious