//======================================== Класс C_GUI ============================================
class C_GUI
{
// произвольные пользовательские данные
var int ints[16];
var string strings[16];
// положение и размер элемента в виртуальных координатах [0-8192] относительно родительского
var int vPosX;
var int vPosY;
var int vSizeX;
var int vSizeY;
// фоновая текстура
var string texture;
// отображаемый предмет
var int item;
// отображаемый текст
var string text;
// непрозрачаность текстуры и шрифта (от 0 до 255), 255 - по умолчанию
var int opacity;
// шрифт отображаемого текста, по умолчанию - шрифт экрана
var string font;
// цвет отображаемого текста (белый по умолчанию)
var int fontR;
var int fontG;
var int fontB;
// выравнивание текста по горизонтали и вертикали (-1 = слева/сверху, 0 = по центру, 1 = справа/снизу)
// -1; -1 - по умолчанию
var int hTextAlign;
var int vTextAlign;
// функция обработки нажатых клавиш `func int MyProc(var C_GUI gui)`
var func proc;
};
//======================================== Константы ==============================================
// индекс в массиве hotItem.ints
const int INDEX_HOT_ITEM_KEY = 0;
const int INDEX_HOT_ITEM_SLOT = 1;
// размер ячейки хотбара в пикселах
const int PHotItemSize = 80;
// отступ между ячейками в пикселах
const int PHotBarBorderSize = 1;
// текстура за отображаемым предметом
const string TEXTURE_ITEM_USABLE = "INV_SLOT_HIGHLIGHTED.TGA";
// текстура за отображаемым предметом, которого нет в инвентаре
const string TEXTURE_ITEM_NOTEXIST = "INV_SLOT_EQUIPPED_HIGHLIGHTED.TGA";
// текстура, затеняющая предмет при неактивном хотбаре
const string TEXTURE_ITEM_SHADOWED = "BLACK.TGA";
// коды клавиш
const int KEY_LSHIFT = 42;
const int KEY_RSHIFT = 54;
const int KEY_1 = 2;
const int KEY_2 = 3;
const int KEY_3 = 4;
// состояния тела персонажа
const int BS_STAND = 0;
const int BS_WALK = 1;
const int BS_SNEAK = 2;
const int BS_RUN = 3;
const int BS_SPRINT = 4;
const int BS_ONLY_STATE = 127;
// Modifier / Overlays
const int BS_MOD_HIDDEN = 128;
const int BS_MOD_DRUNK = 256;
const int BS_MOD_NUTS = 512;
const int BS_MOD_BURNING = 1024;
const int BS_MOD_CONTROLLED = 2048;
const int BS_MOD_TRANSFORMED = 4096;
const int BS_MOD_CONTROLLING = 8192;
//===================================== Состояние Хотбара =========================================
// предметы хотбара и их количество
var int HotBarItems[3];
var int HotBarItemsCount;
//========================================== Функции ==============================================
// определение минимума из дух чисел
func int GetMin(var int x, var int y)
{
if (x < y)
{
return x;
};
return y;
};
// функция установки / снятия предмета с хотбара
func void SetHobarItem(var int slot, var int item)
{
if (slot == 0)
{
HotbarItems[0] = item;
};
if (slot == 1)
{
HotbarItems[1] = item;
};
if (slot == 2)
{
HotbarItems[2] = item;
};
HotbarItemsCount = 0;
if (HotbarItems[0] > 0)
{
HotbarItemsCount += 1;
};
if (HotbarItems[1] > 0)
{
HotbarItemsCount += 1;
};
if (HotbarItems[2] > 0)
{
HotbarItemsCount += 1;
};
};
// обработка клаыиш использования/задания предмета
func int HotItemProc(var C_GUI hotItem)
{
// использование предмета
if (Hlp_KeyPressed(KEY_LSHIFT) == true)
{
if (Npc_HasItems(hero, hotItem.item) == 0)
{
return false;
};
if (Hlp_KeyToggled(hotItem.ints[INDEX_HOT_ITEM_KEY]) == false)
{
return false;
};
Npc_ClearAIQueue(hero);
AI_StandUpQuick(hero);
AI_UseItem(hero, hotItem.item);
AI_EquipArmor(hero, hotItem.item);
// не обрабатывать другие ячейки
return true;
};
// задание предмета
if (Hlp_KeyPressed(KEY_RSHIFT) == true)
{
if (Hlp_KeyToggled(hotItem.ints[INDEX_HOT_ITEM_KEY]) == false)
{
return false;
};
var C_Item focus;
focus = Hlp_GetFocusVob(hero);
if (Cast_InstanceIsItem(focus) == false)
{
SetHobarItem(hotItem.ints[INDEX_HOT_ITEM_SLOT], 0);
return true;
};
if (focus.mainflag != ITEM_KAT_FOOD) && (focus.mainflag != ITEM_KAT_ARMOR) && (focus.mainflag != ITEM_KAT_POTIONS)
{
SetHobarItem(hotItem.ints[INDEX_HOT_ITEM_SLOT], 0);
return true;
};
SetHobarItem(hotItem.ints[INDEX_HOT_ITEM_SLOT], Cast_GetInstanceIndex(focus));
return true;
};
return false;
};
//========================================= Прототипы =============================================
// переменная со значением null
var C_GUI GuiScreen;
// прототип ячейки инвентаря
prototype HotItemProto(C_GUI)
{
proc = HotItemProc;
};
// прототип для элемента, который затемнит отображаемый предмет
prototype HotItemShadowedProto(C_GUI)
{
texture = TEXTURE_ITEM_SHADOWED;
opacity = 150;
};
// прототип надписи с клавишей
prototype HotKeyLabelProto(C_GUI)
{
vPosX = 700;
vPosY = vPosX;
vSizeX = 8192 - 2 * vPosX;
vSizeY = 8192 - 2 * vPosY;
};
// прототип надписи с количеством предметов
prototype HotAmountLabelProto(C_GUI)
{
vPosX = 700;
vPosY = vPosX;
vSizeX = 8192 - 2 * vPosX;
vSizeY = 8192 - 2 * vPosY;
// надпись справа/снизу
hTextAlign = 1;
vTextAlign = 1;
};
// прототип хотбара
prototype HotBarProto(C_GUI)
{
// размер = количествово_предметов * ширина_ячейки + (количество_предметов + 1) * ширина_отступа
vSizeX = HotBarItemsCount * GUI_Anx(GuiScreen, PHotItemSize) + (HotBarItemsCount + 1) * GUI_Anx(GuiScreen, PHotBarBorderSize);
// размер = высота ячейки + 2 отступа (сверху и снизу)
vSizeY = GUI_Any(GuiScreen, PHotItemSize) + 2 * GUI_Any(GuiScreen, PHotBarBorderSize);
// горизонтальное положение - по центру
vPosX = 8192 / 2 - vSizeX / 2;
// вертикальное положение - где-то внизу экрана
vPosY = 7000;
};
// плагин вызывает эту функцию каждый кадр (из-за суффикса)
func void ShowHotbar_GuiPerFrame()
{
// в диалоге хотбар не должен работать
if (InfoManager_HasFinished() == false)
{
return;
};
// определяет, нужно ли обрабатывать нажатия клавищ
var int handleKeys;
handleKeys = true;
// проверяем состояние тела
var int bodyState;
bodyState = Npc_GetBodyState(hero) & BS_ONLY_STATE;
if (bodyState != BS_STAND) && (bodyState != BS_RUN) && (bodyState != BS_WALK)
{
handleKeys = false;
};
if Npc_HasBodyFlag(hero, BS_MOD_TRANSFORMED) || Npc_HasBodyFlag(hero, BS_MOD_CONTROLLED)
{
handleKeys = false;
};
// в боевой стойке клавиши не обрабатываем
if (Npc_IsInFightMode(hero, 0) == false)
{
handleKeys = false;
};
var C_GUI hotBar;
var C_GUI hotItem;
var C_GUI label;
var int vItemSizeX;
var int vItemSizeY;
var int vBorderSizeX;
var int vBorderSizeY;
var int counter;
var int amount;
// создаем главный элемент
hotBar = GUI_Create(GuiScreen, HotBarProto);
// определяем виртуальные размеры ячеек и отступов
vItemSizeX = GUI_Anx(hotBar, PHotItemSize);
vItemSizeY = GUI_Any(hotBar, PHotItemSize);
vBorderSizeX = GUI_Anx(hotBar, PHotBarBorderSize);
vBorderSizeY = GUI_Any(hotBar, PHotBarBorderSize);
// счётчик отображаемых элементов
counter = 0;
// текст клавиши
var string keyText;
// -------------- 1 ------------------------
// создаем ячейку хотбара как дочерний элемент
hotItem = GUI_Create(hotBar, HotItemProto);
// специфичные для данной ячейки параметры
hotItem.item = HotBarItems[0];
hotItem.ints[INDEX_HOT_ITEM_KEY] = KEY_1;
hotItem.ints[INDEX_HOT_ITEM_SLOT] = 0;
keyText = "1";
// не отображаем количество больше 999
amount = GetMin(999, Npc_HasItems(hero, hotItem.item));
if (hotItem.item > 0)
{
// отступ + (размер ячейки + отступ) за каждый уже отображенный предмет
hotItem.vPosX = vBorderSizeX + counter * (vItemSizeX + vBorderSizeX);
hotItem.vPosY = vBorderSizeY;
hotItem.vSizeX = vItemSizeX;
hotItem.vSizeY = vItemSizeY;
if (amount == 0)
{
hotItem.texture = TEXTURE_ITEM_NOTEXIST;
}
else
{
hotItem.texture = TEXTURE_ITEM_USABLE;
};
// затеняем предмет
if (handleKeys == false)
{
hotItem = GUI_Create(hotItem, HotItemShadowedProto);
};
label = GUI_Create(hotItem, HotKeyLabelProto);
label.text = keyText;
label = GUI_Create(hotItem, HotAmountLabelProto);
label.text = IntToString(amount);
counter += 1;
};
// -------------- 2 ------------------------
hotItem = GUI_Create(hotBar, HotItemProto);
// специфичные для данной ячейки параметры
hotItem.item = HotBarItems[1];
hotItem.ints[INDEX_HOT_ITEM_KEY] = KEY_2;
hotItem.ints[INDEX_HOT_ITEM_SLOT] = 1;
keyText = "2";
amount = GetMin(999, Npc_HasItems(hero, hotItem.item));
if (hotItem.item > 0)
{
// отступ + (размер ячейки + отступ) за каждый уже отображенный предмет
hotItem.vPosX = vBorderSizeX + counter * (vItemSizeX + vBorderSizeX);
hotItem.vPosY = vBorderSizeY;
hotItem.vSizeX = vItemSizeX;
hotItem.vSizeY = vItemSizeY;
if (amount == 0)
{
hotItem.texture = TEXTURE_ITEM_NOTEXIST;
}
else
{
hotItem.texture = TEXTURE_ITEM_USABLE;
};
// затеняем предмет
if (handleKeys == false)
{
hotItem = GUI_Create(hotItem, HotItemShadowedProto);
};
label = GUI_Create(hotItem, HotKeyLabelProto);
label.text = keyText;
label = GUI_Create(hotItem, HotAmountLabelProto);
label.text = IntToString(amount);
counter += 1;
};
// -------------- 3 ------------------------
hotItem = GUI_Create(hotBar, HotItemProto);
// специфичные для данной ячейки параметры
hotItem.item = HotBarItems[2];
hotItem.ints[INDEX_HOT_ITEM_KEY] = KEY_3;
hotItem.ints[INDEX_HOT_ITEM_SLOT] = 2;
keyText = "3";
amount = GetMin(999, Npc_HasItems(hero, hotItem.item));
if (hotItem.item > 0)
{
// отступ + (размер ячейки + отступ) за каждый уже отображенный предмет
hotItem.vPosX = vBorderSizeX + counter * (vItemSizeX + vBorderSizeX);
hotItem.vPosY = vBorderSizeY;
hotItem.vSizeX = vItemSizeX;
hotItem.vSizeY = vItemSizeY;
if (amount == 0)
{
hotItem.texture = TEXTURE_ITEM_NOTEXIST;
}
else
{
hotItem.texture = TEXTURE_ITEM_USABLE;
};
// затеняем предмет
if (handleKeys == false)
{
hotItem = GUI_Create(hotItem, HotItemShadowedProto);
};
label = GUI_Create(hotItem, HotKeyLabelProto);
label.text = keyText;
label = GUI_Create(hotItem, HotAmountLabelProto);
label.text = IntToString(amount);
counter += 1;
};
// ====================================================================
// обрабатываем нажатые клавиши (обход от дочерних элементов к корневым)
if (handleKeys == true)
{
GUI_Proc(hotBar);
};
// ставим корневой элемент в очередь на отрисовку
GUI_Draw(hotBar);
};
а есть настроение или желание дорабатывать нюансы хуманс-ремастера в рамках юниона ?